# CMakeLists.txt

cmake_minimum_required(VERSION 3.10)
project(shadertoy VERSION 1.00)

# Estàndard de C++
set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED True)

# Política CMP0072: usar GLVND (libOpenGL/libGLX) en lloc de la libGL clàssica.
cmake_policy(SET CMP0072 NEW)
set(OpenGL_GL_PREFERENCE GLVND)

# Opció per a empaquetat de bundle macOS (.app). El Makefile la passa amb -DMACOS_BUNDLE=ON.
option(MACOS_BUNDLE "Build for macOS .app bundle (rpath into ../Frameworks)" OFF)

# --- LISTA EXPLÍCITA DE FUENTES ---
set(APP_SOURCES
    source/main.cpp
    source/rendering/shader_backend.cpp
    source/rendering/opengl_shader_backend.cpp
    source/rendering/sdl3gpu/sdl3gpu_shader_backend.cpp
    source/audio/jail_audio.cpp
)

# Fuentes de librerías de terceros
set(EXTERNAL_SOURCES
    source/external/glad/src/glad.c
    source/external/stb_vorbis_impl.cpp
)

# Configuració de SDL3
find_package(SDL3 REQUIRED CONFIG REQUIRED COMPONENTS SDL3)
message(STATUS "SDL3 trobat: ${SDL3_INCLUDE_DIRS}")

# --- COMPILACIÓ DE SHADERS (Vulkan SPIR-V) ---
# Es fa a cada build: compile_shaders.cmake fa check de timestamps, no
# recompila el que ja està al dia.
find_program(GLSLC_EXE NAMES glslc)
if(GLSLC_EXE)
    message(STATUS "glslc trobat: ${GLSLC_EXE}")
    add_custom_target(compile_shaders ALL
        COMMAND ${CMAKE_COMMAND}
            -D GLSLC=${GLSLC_EXE}
            -D SHADERS_DIR=${CMAKE_SOURCE_DIR}/data/shaders
            -P ${CMAKE_SOURCE_DIR}/tools/shaders/compile_shaders.cmake
        WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
        COMMENT "Compiling .vk.glsl shaders to SPIR-V")
else()
    message(STATUS "glslc no trobat — el target compile_shaders no estarà disponible")
endif()

# --- RECURSO DE WINDOWS (icona) ---
# A Windows compilem release/windows/shadertoy.rc amb windres via CMake.
# El .rc fa referència a icon.ico per nom; afegim --include-dir perquè el
# trobi a release/icons/.
if(WIN32)
    enable_language(RC)
    set(WIN_RC_FILE ${CMAKE_SOURCE_DIR}/release/windows/shadertoy.rc)
    set_source_files_properties(${WIN_RC_FILE} PROPERTIES
        COMPILE_FLAGS "--include-dir=${CMAKE_SOURCE_DIR}/release/icons")
    list(APPEND APP_SOURCES ${WIN_RC_FILE})
endif()

# --- AÑADIR EJECUTABLE ---
add_executable(${PROJECT_NAME} ${APP_SOURCES} ${EXTERNAL_SOURCES})

# --- DIRECTORIOS DE INCLUSIÓN ---
target_include_directories(${PROJECT_NAME} PUBLIC
    "${CMAKE_SOURCE_DIR}/source"
    "${CMAKE_SOURCE_DIR}/source/external/glad/include"
    "${CMAKE_SOURCE_DIR}/source/external"
)

# Enllaçar la llibreria SDL3
target_link_libraries(${PROJECT_NAME} PRIVATE SDL3::SDL3)


# --- CONFIGURACIÓ PLATAFORMES I COMPILADOR  ---
# Flags de compilació
target_compile_options(${PROJECT_NAME} PRIVATE -Wall)
target_compile_options(${PROJECT_NAME} PRIVATE $<$<CONFIG:RELEASE>:-Os -ffunction-sections -fdata-sections>)

# Definir _DEBUG en mode Debug
target_compile_definitions(${PROJECT_NAME} PRIVATE $<$<CONFIG:DEBUG>:_DEBUG>)


# Configuració específica per a cada plataforma
if(WIN32)
    target_compile_definitions(${PROJECT_NAME} PRIVATE WINDOWS_BUILD)
    target_link_libraries(${PROJECT_NAME} PRIVATE ws2_32 mingw32 opengl32)
elseif(APPLE)
    target_compile_definitions(${PROJECT_NAME} PRIVATE MACOS_BUILD)
    target_compile_options(${PROJECT_NAME} PRIVATE -Wno-deprecated)
    if(NOT CMAKE_OSX_ARCHITECTURES)
        set(CMAKE_OSX_ARCHITECTURES "arm64")
    endif()
    if(MACOS_BUNDLE)
        target_compile_definitions(${PROJECT_NAME} PRIVATE MACOS_BUNDLE)
        target_link_options(${PROJECT_NAME} PRIVATE
            -rpath @executable_path/../Frameworks/
        )
    endif()
elseif(UNIX AND NOT APPLE)
    target_compile_definitions(${PROJECT_NAME} PRIVATE LINUX_BUILD)
endif()

# Configuració comuna per a OpenGL
if(NOT WIN32)
    find_package(OpenGL REQUIRED)
    if(OPENGL_FOUND)
        message(STATUS "OpenGL trobat: ${OPENGL_LIBRARIES}")
        target_link_libraries(${PROJECT_NAME} PRIVATE ${OPENGL_LIBRARIES})
    else()
        message(FATAL_ERROR "OpenGL no trobat")
    endif()
endif()

# El binari surt a l'arrel del projecte (com fins ara).
set_target_properties(${PROJECT_NAME} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_SOURCE_DIR})