# compile_spirv.cmake
# Compila shaders GLSL a SPIR-V i genera headers C++ embedibles.
# Multiplataforma: Windows, macOS, Linux (no requereix bash ni xxd).
#
# Invocat per CMakeLists.txt amb:
#   cmake -D GLSLC=<path> -D SHADERS_DIR=<path> -D HEADERS_DIR=<path> -P compile_spirv.cmake
#
# També es pot executar manualment des de l'arrel del projecte:
#   cmake -D GLSLC=glslc -D SHADERS_DIR=data/shaders \
#         -D HEADERS_DIR=source/core/rendering/sdl3gpu/spv \
#         -P tools/shaders/compile_spirv.cmake

cmake_minimum_required(VERSION 3.10)
cmake_policy(SET CMP0007 NEW)

# Llista de shaders a compilar: font relativa a SHADERS_DIR
set(SHADER_SOURCES
    "postfx.vert"
    "postfx.frag"
)

# Nom de la variable C++ per a cada shader (mateix ordre)
set(SHADER_VARS
    "kpostfx_vert_spv"
    "kpostfx_frag_spv"
)

list(LENGTH SHADER_SOURCES NUM_SHADERS)
math(EXPR LAST_IDX "${NUM_SHADERS} - 1")

foreach(IDX RANGE ${LAST_IDX})
    list(GET SHADER_SOURCES ${IDX} SRC_NAME)
    list(GET SHADER_VARS    ${IDX} VAR)

    # Derivem el nom del header a partir de la variable: kpostfx_vert_spv → postfx_vert_spv.h
    string(REGEX REPLACE "^k" "" HDR_BASE "${VAR}")
    set(SRC "${SHADERS_DIR}/${SRC_NAME}")
    set(SPV "${HEADERS_DIR}/${HDR_BASE}.spv")
    set(HDR "${HEADERS_DIR}/${HDR_BASE}.h")

    message(STATUS "Compilant ${SRC} ...")

    execute_process(
        COMMAND "${GLSLC}" "${SRC}" -o "${SPV}"
        RESULT_VARIABLE GLSLC_RESULT
        ERROR_VARIABLE  GLSLC_ERROR
    )

    if(NOT GLSLC_RESULT EQUAL 0)
        message(FATAL_ERROR "glslc ha fallat per a ${SRC}:\n${GLSLC_ERROR}")
    endif()

    # Llegim el binari SPV com a hex (sense separadors) i el dividim en bytes.
    file(READ "${SPV}" HEX_DATA HEX)
    string(REGEX MATCHALL ".." BYTES "${HEX_DATA}")
    list(LENGTH BYTES NUM_BYTES)

    set(ARRAY_BODY "")
    foreach(BYTE ${BYTES})
        string(APPEND ARRAY_BODY "    0x${BYTE},\n")
    endforeach()

    file(WRITE "${HDR}"
        "#pragma once\n"
        "#include <cstddef>\n"
        "#include <cstdint>\n"
        "static const uint8_t ${VAR}[] = {\n"
        "${ARRAY_BODY}"
        "};\n"
        "static const size_t ${VAR}_size = ${NUM_BYTES};\n"
    )

    file(REMOVE "${SPV}")
    message(STATUS "  -> ${HDR} (${NUM_BYTES} bytes)")
endforeach()

message(STATUS "Shaders SPIR-V compilats correctament.")