# CMakeLists.txt

cmake_minimum_required(VERSION 3.10)

# La versió de l'app es defineix una sola vegada a source/utils/defines.hpp
# (Defines::VERSION). El Makefile ja la grepeja per als noms de release; aqui
# l'extreiem perque project(... VERSION ...) i tots els consumidors interns
# de CMake (CPack, install, etc.) usin la mateixa font de veritat.
file(READ "${CMAKE_CURRENT_SOURCE_DIR}/source/utils/defines.hpp" _DEFINES_CONTENT)
string(REGEX MATCH "VERSION = \"([0-9]+\\.[0-9]+\\.[0-9]+)\"" _ "${_DEFINES_CONTENT}")
set(APP_VERSION "${CMAKE_MATCH_1}")
if(APP_VERSION STREQUAL "")
    message(FATAL_ERROR "No s'ha pogut extreure VERSION de source/utils/defines.hpp")
endif()

project(coffee_crisis VERSION ${APP_VERSION})

# Tipus de build per defecte (Debug) si no se n'ha especificat cap
if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
    set(CMAKE_BUILD_TYPE Debug CACHE STRING "" FORCE)
endif()

# Establecer estándar de C++
set(CMAKE_CXX_STANDARD 20)
set(CMAKE_CXX_STANDARD_REQUIRED True)
set(CMAKE_EXPORT_COMPILE_COMMANDS ON)

# --- GENERACIÓN DE VERSIÓN AUTOMÁTICA ---
# Si GIT_HASH se ha pasado desde fuera (p.ej. desde el Makefile via -DGIT_HASH=xxx),
# lo usamos tal cual. Esto evita problemas con Docker/emscripten, donde git aborta por
# "dubious ownership" en el volumen montado. En builds locales sin -DGIT_HASH, se
# resuelve aquí ejecutando git directamente.
if(NOT DEFINED GIT_HASH OR GIT_HASH STREQUAL "")
    find_package(Git QUIET)
    if(GIT_FOUND)
        execute_process(
            COMMAND ${GIT_EXECUTABLE} rev-parse --short=7 HEAD
            WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
            OUTPUT_VARIABLE GIT_HASH
            OUTPUT_STRIP_TRAILING_WHITESPACE
            ERROR_QUIET
        )
    endif()
    if(NOT DEFINED GIT_HASH OR GIT_HASH STREQUAL "")
        set(GIT_HASH "unknown")
    endif()
endif()

# Configurar archivo de versión
configure_file(${CMAKE_SOURCE_DIR}/source/version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)

# Define el directorio de los archivos fuente
set(DIR_SOURCES "${CMAKE_SOURCE_DIR}/source")

# --- LISTA EXPLÍCITA DE FUENTES ---
set(APP_SOURCES
    source/main.cpp

    # --- core/audio ---
    source/core/audio/audio.cpp
    source/core/audio/audio_adapter.cpp

    # --- core/input ---
    source/core/input/global_inputs.cpp
    source/core/input/input.cpp
    source/core/input/mouse.cpp

    # --- core/locale ---
    source/core/locale/lang.cpp

    # --- core/rendering ---
    source/core/rendering/animatedsprite.cpp
    source/core/rendering/fade.cpp
    source/core/rendering/movingsprite.cpp
    source/core/rendering/notifications.cpp
    source/core/rendering/screen.cpp
    source/core/rendering/sdl3gpu/sdl3gpu_shader.cpp
    source/core/rendering/smartsprite.cpp
    source/core/rendering/sprite.cpp
    source/core/rendering/text.cpp
    source/core/rendering/texture.cpp
    source/core/rendering/writer.cpp

    # --- core/resources ---
    source/core/resources/asset.cpp
    source/core/resources/resource.cpp
    source/core/resources/resource_helper.cpp
    source/core/resources/resource_loader.cpp
    source/core/resources/resource_pack.cpp

    # --- core/system ---
    source/core/system/delta_time.cpp
    source/core/system/demo.cpp
    source/core/system/director.cpp

    # --- game ---
    source/game/game.cpp
    source/game/options.cpp

    # --- game/entities ---
    source/game/entities/balloon.cpp
    source/game/entities/bullet.cpp
    source/game/entities/item.cpp
    source/game/entities/player.cpp

    # --- game/scenes ---
    source/game/scenes/instructions.cpp
    source/game/scenes/intro.cpp
    source/game/scenes/logo.cpp
    source/game/scenes/title.cpp

    # --- game/ui ---
    source/game/ui/menu.cpp

    # --- utils ---
    source/utils/utils.cpp
)

# Configuración de SDL3
if(EMSCRIPTEN)
    # En Emscripten, SDL3 se compila desde source con FetchContent
    include(FetchContent)
    FetchContent_Declare(
        SDL3
        GIT_REPOSITORY https://github.com/libsdl-org/SDL.git
        GIT_TAG release-3.4.4
        GIT_SHALLOW TRUE
    )
    set(SDL_SHARED OFF CACHE BOOL "" FORCE)
    set(SDL_STATIC ON CACHE BOOL "" FORCE)
    set(SDL_TEST_LIBRARY OFF CACHE BOOL "" FORCE)
    FetchContent_MakeAvailable(SDL3)
    message(STATUS "SDL3 compilado desde source para Emscripten")
else()
    find_package(SDL3 REQUIRED CONFIG REQUIRED COMPONENTS SDL3)
    message(STATUS "SDL3 encontrado: ${SDL3_INCLUDE_DIRS}")
endif()

# --- SHADER COMPILATION (Linux/Windows only - macOS uses Metal, Emscripten no soporta SDL3 GPU) ---
if(NOT APPLE AND NOT EMSCRIPTEN)
    find_program(GLSLC_EXE NAMES glslc)

    set(SHADERS_DIR "${CMAKE_SOURCE_DIR}/data/shaders")
    set(HEADERS_DIR "${CMAKE_SOURCE_DIR}/source/core/rendering/sdl3gpu/spv")

    set(ALL_SHADER_HEADERS
        "${HEADERS_DIR}/postfx_vert_spv.h"
        "${HEADERS_DIR}/postfx_frag_spv.h"
        "${HEADERS_DIR}/crtpi_frag_spv.h"
    )
    set(ALL_SHADER_SOURCES
        "${SHADERS_DIR}/postfx.vert"
        "${SHADERS_DIR}/postfx.frag"
        "${SHADERS_DIR}/crtpi_frag.glsl"
    )

    if(GLSLC_EXE)
        add_custom_command(
            OUTPUT  ${ALL_SHADER_HEADERS}
            COMMAND ${CMAKE_COMMAND}
                    -D GLSLC=${GLSLC_EXE}
                    -D SHADERS_DIR=${SHADERS_DIR}
                    -D HEADERS_DIR=${HEADERS_DIR}
                    -P ${CMAKE_SOURCE_DIR}/tools/shaders/compile_spirv.cmake
            DEPENDS ${ALL_SHADER_SOURCES}
            WORKING_DIRECTORY "${CMAKE_SOURCE_DIR}"
            COMMENT "Compilando shaders SPIR-V..."
        )
        add_custom_target(shaders DEPENDS ${ALL_SHADER_HEADERS})
        message(STATUS "glslc encontrado: shaders se compilarán automáticamente")
    else()
        foreach(HDR ${ALL_SHADER_HEADERS})
            if(NOT EXISTS "${HDR}")
                message(FATAL_ERROR
                    "glslc no encontrado y header SPIR-V no existe: ${HDR}\n"
                    "  Instala glslc: sudo apt install glslang-tools  (Linux)\n"
                    "                 choco install vulkan-sdk         (Windows)"
                )
            endif()
        endforeach()
        message(STATUS "glslc no encontrado - usando headers SPIR-V precompilados")
    endif()
else()
    if(EMSCRIPTEN)
        message(STATUS "Emscripten: shaders SPIR-V omitidos (SDL3 GPU no soportado en WebGL2)")
    else()
        message(STATUS "macOS: shaders SPIR-V omitidos (usa Metal inline)")
    endif()
endif()

# Añadir ejecutable principal
if(EMSCRIPTEN)
    # En Emscripten no compilem sdl3gpu_shader (SDL3 GPU no està suportat en WebGL2)
    set(APP_SOURCES_WASM ${APP_SOURCES})
    list(REMOVE_ITEM APP_SOURCES_WASM source/core/rendering/sdl3gpu/sdl3gpu_shader.cpp)
    add_executable(${PROJECT_NAME} ${APP_SOURCES_WASM})
else()
    add_executable(${PROJECT_NAME} ${APP_SOURCES})
endif()

if(NOT APPLE AND NOT EMSCRIPTEN AND GLSLC_EXE)
    add_dependencies(${PROJECT_NAME} shaders)
endif()

# Includes relatius a source/ (p.e. `#include "core/rendering/texture.h"`)
# ${CMAKE_BINARY_DIR} per al version.h generat per configure_file.
target_include_directories(${PROJECT_NAME} PRIVATE ${DIR_SOURCES} ${CMAKE_BINARY_DIR})

# Flags de compilació per-target
target_compile_options(${PROJECT_NAME} PRIVATE -Wall -Wextra -Wpedantic)
target_compile_options(${PROJECT_NAME} PRIVATE $<$<CONFIG:RELEASE>:-Os -ffunction-sections -fdata-sections>)

# Añadir definiciones de compilación dependiendo del tipo de build
target_compile_definitions(${PROJECT_NAME} PRIVATE
    $<$<CONFIG:DEBUG>:DEBUG>
    $<$<CONFIG:RELEASE>:RELEASE_BUILD>
)

# Enlazar bibliotecas
target_link_libraries(${PROJECT_NAME} PRIVATE SDL3::SDL3)

# Configuración específica para cada plataforma
if(WIN32)
    target_compile_definitions(${PROJECT_NAME} PRIVATE WINDOWS_BUILD)
    target_link_libraries(${PROJECT_NAME} PRIVATE ws2_32 mingw32 gdi32 winmm imm32 ole32 version)
elseif(APPLE)
    target_compile_definitions(${PROJECT_NAME} PRIVATE MACOS_BUILD)
    target_compile_options(${PROJECT_NAME} PRIVATE -Wno-deprecated)
    if(NOT CMAKE_OSX_ARCHITECTURES)
        set(CMAKE_OSX_ARCHITECTURES "arm64")
    endif()
    if(MACOS_BUNDLE)
        target_compile_definitions(${PROJECT_NAME} PRIVATE MACOS_BUNDLE)
        target_link_options(${PROJECT_NAME} PRIVATE
            -framework SDL3
            -F ${CMAKE_SOURCE_DIR}/release/macos/frameworks/SDL3.xcframework/macos-arm64_x86_64
            -rpath @executable_path/../Frameworks/
        )
    endif()
elseif(EMSCRIPTEN)
    target_compile_definitions(${PROJECT_NAME} PRIVATE EMSCRIPTEN_BUILD NO_SHADERS)
    # En wasm NO empaquetamos un resources.pack: el propio --preload-file de
    # emscripten ya hace el mismo trabajo (bundle del directorio en un .data),
    # así que metemos directamente 'data' y dejamos que el Resource lea por
    # filesystem (MEMFS). Evita doble empaquetado y el uso de memoria extra.
    target_link_options(${PROJECT_NAME} PRIVATE
        "SHELL:--preload-file ${CMAKE_SOURCE_DIR}/data@/data"
        "SHELL:--preload-file ${CMAKE_SOURCE_DIR}/gamecontrollerdb.txt@/gamecontrollerdb.txt"
        -sALLOW_MEMORY_GROWTH=1
        -sMAX_WEBGL_VERSION=2
    )
    set_target_properties(${PROJECT_NAME} PROPERTIES SUFFIX ".html")
elseif(UNIX AND NOT APPLE)
    target_compile_definitions(${PROJECT_NAME} PRIVATE LINUX_BUILD)
    target_link_options(${PROJECT_NAME} PRIVATE -Wl,--gc-sections)
endif()

# ==============================================================================
# STATIC ANALYSIS TARGETS
# ==============================================================================

find_program(CLANG_TIDY_EXE NAMES clang-tidy)
find_program(CLANG_FORMAT_EXE NAMES clang-format)
find_program(CPPCHECK_EXE NAMES cppcheck)

# Recopilar todos los archivos fuente para analisis
file(GLOB_RECURSE ALL_SOURCE_FILES
    "${CMAKE_SOURCE_DIR}/source/*.cpp"
    "${CMAKE_SOURCE_DIR}/source/*.h"
)

set(CLANG_TIDY_SOURCES ${ALL_SOURCE_FILES})

# Para cppcheck, pasar solo .cpp (los headers se procesan transitivamente).
set(CPPCHECK_SOURCES ${ALL_SOURCE_FILES})
list(FILTER CPPCHECK_SOURCES INCLUDE REGEX ".*\\.cpp$")
list(FILTER CPPCHECK_SOURCES EXCLUDE REGEX ".*/source/external/.*")

# Targets de clang-tidy
if(CLANG_TIDY_EXE)
    add_custom_target(tidy
        COMMAND ${CLANG_TIDY_EXE}
            -p ${CMAKE_BINARY_DIR}
            ${CLANG_TIDY_SOURCES}
        WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
        COMMENT "Running clang-tidy..."
    )

    add_custom_target(tidy-fix
        COMMAND ${CLANG_TIDY_EXE}
            -p ${CMAKE_BINARY_DIR}
            --fix
            ${CLANG_TIDY_SOURCES}
        WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
        COMMENT "Running clang-tidy with fixes..."
    )
else()
    message(STATUS "clang-tidy no encontrado - targets 'tidy' y 'tidy-fix' no disponibles")
endif()

# Targets de clang-format
if(CLANG_FORMAT_EXE)
    add_custom_target(format
        COMMAND ${CLANG_FORMAT_EXE}
            -i
            ${ALL_SOURCE_FILES}
        WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
        COMMENT "Running clang-format..."
    )

    add_custom_target(format-check
        COMMAND ${CLANG_FORMAT_EXE}
            --dry-run
            --Werror
            ${ALL_SOURCE_FILES}
        WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
        COMMENT "Checking clang-format..."
    )
else()
    message(STATUS "clang-format no encontrado - targets 'format' y 'format-check' no disponibles")
endif()

# Target de cppcheck
if(CPPCHECK_EXE)
    add_custom_target(cppcheck
        COMMAND ${CPPCHECK_EXE}
            --enable=warning,style,performance,portability
            --std=c++20
            --language=c++
            --inline-suppr
            --suppress=missingIncludeSystem
            --suppress=toomanyconfigs
            --suppress=*:*/source/external/*
            --suppress=*:*/source/core/rendering/sdl3gpu/spv/*
            --quiet
            -I ${CMAKE_SOURCE_DIR}/source
            ${CPPCHECK_SOURCES}
        WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
        COMMENT "Running cppcheck..."
    )
else()
    message(STATUS "cppcheck no encontrado - target 'cppcheck' no disponible")
endif()

# --- EINA STANDALONE: pack_resources ---
# Executable auxiliar que empaqueta `data/` a `resources.pack`.
# No es compila per defecte (EXCLUDE_FROM_ALL). Build explícit:
#   cmake --build build --target pack_resources
# Després executar: ./build/pack_resources data resources.pack
if(NOT EMSCRIPTEN)
    add_executable(pack_resources EXCLUDE_FROM_ALL
        tools/pack_resources/pack_resources.cpp
        source/core/resources/resource_pack.cpp
    )
    target_include_directories(pack_resources PRIVATE "${CMAKE_SOURCE_DIR}/source")
    target_compile_options(pack_resources PRIVATE -Wall -Wextra -Wpedantic)

    # Regeneració automàtica de resources.pack en cada build si canvia data/.
    file(GLOB_RECURSE DATA_FILES CONFIGURE_DEPENDS "${CMAKE_SOURCE_DIR}/data/*")
    set(RESOURCE_PACK "${CMAKE_BINARY_DIR}/resources.pack")

    add_custom_command(
        OUTPUT ${RESOURCE_PACK}
        COMMAND $<TARGET_FILE:pack_resources>
            "${CMAKE_SOURCE_DIR}/data"
            "${RESOURCE_PACK}"
        DEPENDS pack_resources ${DATA_FILES}
        WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
        COMMENT "Empaquetant data/ → resources.pack"
        VERBATIM
    )

    add_custom_target(resource_pack ALL DEPENDS ${RESOURCE_PACK})
    add_dependencies(${PROJECT_NAME} resource_pack)

    # --- CÒPIA DE gamecontrollerdb.txt AL COSTAT DEL BINARI ---
    # SDL_AddGamepadMappingsFromFile només llegeix del filesystem real (no del
    # pack), així que el fitxer ha de viure al directori del binari. Es copia
    # només si existeix per no fallar la build d'algú que encara no ha fet
    # `make controllerdb`.
    if(EXISTS "${CMAKE_SOURCE_DIR}/gamecontrollerdb.txt")
        set(CONTROLLER_DB "${CMAKE_BINARY_DIR}/gamecontrollerdb.txt")
        add_custom_command(
            OUTPUT ${CONTROLLER_DB}
            COMMAND ${CMAKE_COMMAND} -E copy_if_different
                "${CMAKE_SOURCE_DIR}/gamecontrollerdb.txt"
                "${CONTROLLER_DB}"
            DEPENDS "${CMAKE_SOURCE_DIR}/gamecontrollerdb.txt"
            COMMENT "Copiant gamecontrollerdb.txt → build/"
            VERBATIM
        )
        add_custom_target(controller_db ALL DEPENDS ${CONTROLLER_DB})
        add_dependencies(${PROJECT_NAME} controller_db)
    endif()
endif()