# CMakeLists.txt

cmake_minimum_required(VERSION 3.10)
project(coffee_crisis_arcade_edition VERSION 2.00)

# Establecer estándar de C++
set(CMAKE_CXX_STANDARD 20)
set(CMAKE_CXX_STANDARD_REQUIRED True)

# Establece la política CMP0072 para indicar cómo se debe seleccionar la implementación de OpenGL.
# En este caso, se elige la opción "GLVND", que utiliza bibliotecas modernas y modulares (libOpenGL, libGLX),
# en lugar de la biblioteca OpenGL clásica (libGL). Esto mejora la compatibilidad con drivers recientes
# y evita ambigüedades cuando se encuentran múltiples implementaciones de OpenGL en el sistema.
cmake_policy(SET CMP0072 NEW)
set(OpenGL_GL_PREFERENCE GLVND)


# --- 1. LISTA EXPLÍCITA DE FUENTES ---
set(APP_SOURCES
    # --- Archivos Principales del Sistema ---
    source/main.cpp
    source/director.cpp
    source/section.cpp
    source/screen.cpp
    source/resource.cpp
    source/asset.cpp
    source/audio.cpp
    source/input.cpp
    source/options.cpp
    source/lang.cpp
    source/param.cpp
    source/utils.cpp
    source/global_events.cpp
    source/global_inputs.cpp
    
    # --- UI (User Interface) ---
    source/ui/service_menu.cpp
    source/ui/menu_renderer.cpp
    source/ui/ui_message.cpp
    
    # --- Lógica del Juego ---
    source/balloon_formations.cpp
    source/balloon_manager.cpp
    source/balloon.cpp
    source/bullet.cpp
    source/enter_name.cpp
    source/explosions.cpp
    source/game_logo.cpp
    source/item.cpp
    source/manage_hiscore_table.cpp
    source/player.cpp
    source/scoreboard.cpp
    
    # --- Escenas ---
    source/sections/credits.cpp
    source/sections/game.cpp
    source/sections/hiscore_table.cpp
    source/sections/instructions.cpp
    source/sections/intro.cpp
    source/sections/logo.cpp
    source/sections/title.cpp
    
    # --- Sprites y Gráficos ---
    source/sprite.cpp
    source/animated_sprite.cpp
    source/moving_sprite.cpp
    source/path_sprite.cpp
    source/smart_sprite.cpp
    source/background.cpp
    source/tiled_bg.cpp
    source/fade.cpp
    source/texture.cpp
    
    # --- Otros ---
    source/define_buttons.cpp
    source/mouse.cpp
    source/notifier.cpp
    source/stage.cpp
    source/tabe.cpp
    source/text.cpp
    source/writer.cpp
)

# Fuentes de librerías de terceros
set(EXTERNAL_SOURCES
    source/external/jail_audio.cpp
    source/external/jail_shader.cpp
    source/external/json.hpp
    source/external/gif.cpp 
)


# Configuración de SDL3
find_package(SDL3 REQUIRED CONFIG REQUIRED COMPONENTS SDL3)
message(STATUS "SDL3 encontrado: ${SDL3_INCLUDE_DIRS}")

# --- 2. AÑADIR EJECUTABLE ---
add_executable(${PROJECT_NAME} ${APP_SOURCES} ${EXTERNAL_SOURCES})

# --- 3. DIRECTORIOS DE INCLUSIÓN ---
target_include_directories(${PROJECT_NAME} PUBLIC
    "${CMAKE_SOURCE_DIR}/source"
    "${CMAKE_SOURCE_DIR}/source/external" 
)

# Enlazar la librería SDL3
target_link_libraries(${PROJECT_NAME} PRIVATE SDL3::SDL3)


# --- 4. CONFIGURACIÓN PLATAFORMAS Y COMPILADOR  ---
# Configuración de flags de compilación
target_compile_options(${PROJECT_NAME} PRIVATE -Wall)
target_compile_options(${PROJECT_NAME} PRIVATE $<$<CONFIG:RELEASE>:-Os -ffunction-sections -fdata-sections>)

# Definir _DEBUG en modo Debug
target_compile_definitions(${PROJECT_NAME} PRIVATE $<$<CONFIG:DEBUG>:DEBUG>)

# Configuración específica para cada plataforma
if(WIN32)
    target_compile_definitions(${PROJECT_NAME} PRIVATE WINDOWS_BUILD)
    target_link_libraries(${PROJECT_NAME} PRIVATE ws2_32 mingw32 opengl32)
elseif(APPLE)
    target_compile_definitions(${PROJECT_NAME} PRIVATE MACOS_BUILD)
    target_compile_options(${PROJECT_NAME} PRIVATE -Wno-deprecated)
    set(CMAKE_OSX_ARCHITECTURES "arm64")
elseif(UNIX AND NOT APPLE)
    target_compile_definitions(${PROJECT_NAME} PRIVATE LINUX_BUILD)
endif()

# Configuración común para OpenGL
if(NOT WIN32)
    find_package(OpenGL REQUIRED)
    if(OPENGL_FOUND)
        message(STATUS "OpenGL encontrado: ${OPENGL_LIBRARIES}")
        target_link_libraries(${PROJECT_NAME} PRIVATE ${OPENGL_LIBRARIES})
    else()
        message(FATAL_ERROR "OpenGL no encontrado")
    endif()
endif()

# Especificar la ubicación del ejecutable
set_target_properties(${PROJECT_NAME} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_SOURCE_DIR})