# CMakeLists.txt

cmake_minimum_required(VERSION 3.10)
project(coffee_crisis_arcade_edition VERSION 2.00)

# Establecer estándar de C++
set(CMAKE_CXX_STANDARD 20)
set(CMAKE_CXX_STANDARD_REQUIRED True)
set(CMAKE_EXPORT_COMPILE_COMMANDS ON)


# --- GENERACIÓN DE VERSIÓN AUTOMÁTICA ---
# Si GIT_HASH se ha pasado desde fuera (p.ej. desde el Makefile via -DGIT_HASH=xxx),
# lo usamos tal cual. Esto evita problemas con Docker/emscripten, donde git aborta por
# "dubious ownership" en el volumen montado. En builds locales sin -DGIT_HASH, se
# resuelve aquí ejecutando git directamente.
if(NOT DEFINED GIT_HASH OR GIT_HASH STREQUAL "")
    find_package(Git QUIET)
    if(GIT_FOUND)
        execute_process(
            COMMAND ${GIT_EXECUTABLE} rev-parse --short=7 HEAD
            WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
            OUTPUT_VARIABLE GIT_HASH
            OUTPUT_STRIP_TRAILING_WHITESPACE
            ERROR_QUIET
        )
    endif()
    if(NOT DEFINED GIT_HASH OR GIT_HASH STREQUAL "")
        set(GIT_HASH "unknown")
    endif()
endif()

# Configurar archivo de versión
configure_file(${CMAKE_SOURCE_DIR}/source/version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)

# --- 1. LISTA EXPLÍCITA DE FUENTES ---
set(APP_SOURCES
    source/main.cpp

    # --- core/audio ---
    source/core/audio/audio.cpp

    # --- core/input ---
    source/core/input/define_buttons.cpp
    source/core/input/global_inputs.cpp
    source/core/input/input.cpp
    source/core/input/input_types.cpp
    source/core/input/mouse.cpp

    # --- core/locale ---
    source/core/locale/lang.cpp

    # --- core/rendering ---
    source/core/rendering/background.cpp
    source/core/rendering/fade.cpp
    source/core/rendering/gif.cpp
    source/core/rendering/screen.cpp
    source/core/rendering/text.cpp
    source/core/rendering/texture.cpp
    source/core/rendering/tiled_bg.cpp
    source/core/rendering/writer.cpp
    source/core/rendering/sdl3gpu/sdl3gpu_shader.cpp
    source/core/rendering/sprite/animated_sprite.cpp
    source/core/rendering/sprite/card_sprite.cpp
    source/core/rendering/sprite/moving_sprite.cpp
    source/core/rendering/sprite/path_sprite.cpp
    source/core/rendering/sprite/smart_sprite.cpp
    source/core/rendering/sprite/sprite.cpp

    # --- core/resources ---
    source/core/resources/asset.cpp
    source/core/resources/asset_integrated.cpp
    source/core/resources/resource.cpp
    source/core/resources/resource_helper.cpp
    source/core/resources/resource_loader.cpp
    source/core/resources/resource_pack.cpp

    # --- core/system ---
    source/core/system/demo.cpp
    source/core/system/director.cpp
    source/core/system/global_events.cpp
    source/core/system/shutdown.cpp
    source/core/system/system_utils.cpp

    # --- game ---
    source/game/options.cpp

    # --- game/entities ---
    source/game/entities/balloon.cpp
    source/game/entities/bullet.cpp
    source/game/entities/explosions.cpp
    source/game/entities/item.cpp
    source/game/entities/player.cpp
    source/game/entities/tabe.cpp

    # --- game/gameplay ---
    source/game/gameplay/balloon_formations.cpp
    source/game/gameplay/balloon_manager.cpp
    source/game/gameplay/bullet_manager.cpp
    source/game/gameplay/difficulty.cpp
    source/game/gameplay/enter_name.cpp
    source/game/gameplay/game_logo.cpp
    source/game/gameplay/manage_hiscore_table.cpp
    source/game/gameplay/scoreboard.cpp
    source/game/gameplay/stage.cpp

    # --- game/scenes ---
    source/game/scenes/credits.cpp
    source/game/scenes/game.cpp
    source/game/scenes/hiscore_table.cpp
    source/game/scenes/instructions.cpp
    source/game/scenes/intro.cpp
    source/game/scenes/logo.cpp
    source/game/scenes/preload.cpp
    source/game/scenes/title.cpp

    # --- game/ui ---
    source/game/ui/menu_option.cpp
    source/game/ui/menu_renderer.cpp
    source/game/ui/notifier.cpp
    source/game/ui/service_menu.cpp
    source/game/ui/ui_message.cpp
    source/game/ui/window_message.cpp

    # --- utils ---
    source/utils/color.cpp
    source/utils/param.cpp
    source/utils/utils.cpp
)

# Configuración de SDL3
if(EMSCRIPTEN)
    # En Emscripten, SDL3 se compila desde source con FetchContent
    include(FetchContent)
    FetchContent_Declare(
        SDL3
        GIT_REPOSITORY https://github.com/libsdl-org/SDL.git
        GIT_TAG release-3.4.4
        GIT_SHALLOW TRUE
    )
    set(SDL_SHARED OFF CACHE BOOL "" FORCE)
    set(SDL_STATIC ON CACHE BOOL "" FORCE)
    set(SDL_TEST_LIBRARY OFF CACHE BOOL "" FORCE)
    FetchContent_MakeAvailable(SDL3)
    message(STATUS "SDL3 compilado desde source para Emscripten")
else()
    find_package(SDL3 REQUIRED CONFIG REQUIRED COMPONENTS SDL3)
    message(STATUS "SDL3 encontrado: ${SDL3_INCLUDE_DIRS}")
endif()

# --- SHADER COMPILATION (Linux/Windows only - macOS uses Metal, Emscripten no soporta SDL3 GPU) ---
if(NOT APPLE AND NOT EMSCRIPTEN)
    find_program(GLSLC_EXE NAMES glslc)

    set(SHADER_VERT_SRC     "${CMAKE_SOURCE_DIR}/data/shaders/postfx.vert")
    set(SHADER_FRAG_SRC     "${CMAKE_SOURCE_DIR}/data/shaders/postfx.frag")
    set(SHADER_CRTPI_SRC    "${CMAKE_SOURCE_DIR}/data/shaders/crtpi_frag.glsl")
    set(SHADER_UPSCALE_SRC  "${CMAKE_SOURCE_DIR}/data/shaders/upscale.frag")
    set(SHADER_DOWNSCALE_SRC "${CMAKE_SOURCE_DIR}/data/shaders/downscale.frag")

    set(SHADER_VERT_H       "${CMAKE_SOURCE_DIR}/source/core/rendering/sdl3gpu/postfx_vert_spv.h")
    set(SHADER_FRAG_H       "${CMAKE_SOURCE_DIR}/source/core/rendering/sdl3gpu/postfx_frag_spv.h")
    set(SHADER_CRTPI_H      "${CMAKE_SOURCE_DIR}/source/core/rendering/sdl3gpu/crtpi_frag_spv.h")
    set(SHADER_UPSCALE_H    "${CMAKE_SOURCE_DIR}/source/core/rendering/sdl3gpu/upscale_frag_spv.h")
    set(SHADER_DOWNSCALE_H  "${CMAKE_SOURCE_DIR}/source/core/rendering/sdl3gpu/downscale_frag_spv.h")

    set(ALL_SHADER_SOURCES "${SHADER_VERT_SRC}" "${SHADER_FRAG_SRC}" "${SHADER_CRTPI_SRC}" "${SHADER_UPSCALE_SRC}" "${SHADER_DOWNSCALE_SRC}")
    set(ALL_SHADER_HEADERS "${SHADER_VERT_H}" "${SHADER_FRAG_H}" "${SHADER_CRTPI_H}" "${SHADER_UPSCALE_H}" "${SHADER_DOWNSCALE_H}")

    if(GLSLC_EXE)
        set(COMPILE_SHADER_SCRIPT "${CMAKE_SOURCE_DIR}/tools/shaders/compile_shader.cmake")

        macro(add_shader SRC_FILE OUT_H VAR_NAME)
            cmake_parse_arguments(S "" "STAGE" "" ${ARGN})
            add_custom_command(
                OUTPUT  "${OUT_H}"
                COMMAND ${CMAKE_COMMAND}
                    "-DGLSLC=${GLSLC_EXE}"
                    "-DSRC=${SRC_FILE}"
                    "-DOUT_H=${OUT_H}"
                    "-DVAR=${VAR_NAME}"
                    "-DSTAGE=${S_STAGE}"
                    -P "${COMPILE_SHADER_SCRIPT}"
                DEPENDS "${SRC_FILE}" "${COMPILE_SHADER_SCRIPT}"
                COMMENT "Compilando shader: ${VAR_NAME}"
            )
        endmacro()

        add_shader("${SHADER_VERT_SRC}"      "${SHADER_VERT_H}"      "postfx_vert_spv")
        add_shader("${SHADER_FRAG_SRC}"      "${SHADER_FRAG_H}"      "postfx_frag_spv")
        add_shader("${SHADER_CRTPI_SRC}"     "${SHADER_CRTPI_H}"     "crtpi_frag_spv"   STAGE fragment)
        add_shader("${SHADER_UPSCALE_SRC}"   "${SHADER_UPSCALE_H}"   "upscale_frag_spv")
        add_shader("${SHADER_DOWNSCALE_SRC}" "${SHADER_DOWNSCALE_H}" "downscale_frag_spv")

        add_custom_target(shaders DEPENDS ${ALL_SHADER_HEADERS})
        message(STATUS "glslc encontrado: shaders se compilarán automáticamente")
    else()
        foreach(_h IN LISTS ALL_SHADER_HEADERS)
            if(NOT EXISTS "${_h}")
                message(FATAL_ERROR
                    "glslc no encontrado y header SPIR-V no existe: ${_h}\n"
                    "  Instala glslc: sudo apt install glslang-tools  (Linux)\n"
                    "                 choco install vulkan-sdk         (Windows)\n"
                    "  O genera los headers manualmente: tools/shaders/compile_spirv.sh"
                )
            endif()
        endforeach()
        message(STATUS "glslc no encontrado - usando headers SPIR-V precompilados")
    endif()
else()
    if(EMSCRIPTEN)
        message(STATUS "Emscripten: shaders SPIR-V omitidos (SDL3 GPU no soportado en WebGL2)")
    else()
        message(STATUS "macOS: shaders SPIR-V omitidos (usa Metal)")
    endif()
endif()

# --- 2. AÑADIR EJECUTABLE ---
if(EMSCRIPTEN)
    # En Emscripten no compilamos sdl3gpu_shader (SDL3 GPU no está soportado en WebGL2)
    set(APP_SOURCES_WASM ${APP_SOURCES})
    list(REMOVE_ITEM APP_SOURCES_WASM source/core/rendering/sdl3gpu/sdl3gpu_shader.cpp)
    add_executable(${PROJECT_NAME} ${APP_SOURCES_WASM})
else()
    add_executable(${PROJECT_NAME} ${APP_SOURCES})
endif()

if(NOT APPLE AND NOT EMSCRIPTEN AND GLSLC_EXE)
    add_dependencies(${PROJECT_NAME} shaders)
endif()

# --- 3. DIRECTORIOS DE INCLUSIÓN ---
target_include_directories(${PROJECT_NAME} PUBLIC
    "${CMAKE_SOURCE_DIR}/source"
    "${CMAKE_BINARY_DIR}"
)

# Enlazar la librería SDL3
target_link_libraries(${PROJECT_NAME} PRIVATE SDL3::SDL3)


# --- 4. CONFIGURACIÓN PLATAFORMAS Y COMPILADOR  ---
# Configuración de flags de compilación
target_compile_options(${PROJECT_NAME} PRIVATE -Wall)
target_compile_options(${PROJECT_NAME} PRIVATE $<$<CONFIG:RELEASE>:-Os -ffunction-sections -fdata-sections>)

# Definir _DEBUG en modo Debug
target_compile_definitions(${PROJECT_NAME} PRIVATE $<$<CONFIG:DEBUG>:_DEBUG>)

# Descomentar la siguiente línea para activar el modo grabación de demos
# target_compile_definitions(${PROJECT_NAME} PRIVATE RECORDING)


# Configuración específica para cada plataforma
if(WIN32)
    target_compile_definitions(${PROJECT_NAME} PRIVATE WINDOWS_BUILD)
    target_link_libraries(${PROJECT_NAME} PRIVATE ws2_32 mingw32)
elseif(APPLE)
    target_compile_definitions(${PROJECT_NAME} PRIVATE MACOS_BUILD)
    if(NOT CMAKE_OSX_ARCHITECTURES)
        set(CMAKE_OSX_ARCHITECTURES "arm64")
    endif()
    if(MACOS_BUNDLE)
        target_compile_definitions(${PROJECT_NAME} PRIVATE MACOS_BUNDLE)
        target_link_options(${PROJECT_NAME} PRIVATE
            -framework SDL3
            -F ${CMAKE_SOURCE_DIR}/release/macos/frameworks/SDL3.xcframework/macos-arm64_x86_64
            -rpath @executable_path/../Frameworks/
        )
    endif()
elseif(EMSCRIPTEN)
    target_compile_definitions(${PROJECT_NAME} PRIVATE EMSCRIPTEN_BUILD NO_SHADERS)
    # -fexceptions: habilita excepciones C++ (fkyaml, std::runtime_error...) — sin esto cualquier throw llama a abort()
    target_compile_options(${PROJECT_NAME} PRIVATE -fexceptions)
    target_link_options(${PROJECT_NAME} PRIVATE
        "SHELL:--preload-file ${CMAKE_SOURCE_DIR}/data@/data"
        "SHELL:--preload-file ${CMAKE_SOURCE_DIR}/config@/config"
        -fexceptions
        -sALLOW_MEMORY_GROWTH=1
        -sMAX_WEBGL_VERSION=2
        -sINITIAL_MEMORY=67108864
        -sASSERTIONS=1
        # ASYNCIFY solo para permitir emscripten_sleep(0) durante la precarga de recursos
        # (el bucle principal del juego ya usa SDL3 Callback API, no depende de ASYNCIFY).
        -sASYNCIFY=1
    )
    set_target_properties(${PROJECT_NAME} PROPERTIES SUFFIX ".html")
elseif(UNIX AND NOT APPLE)
    target_compile_definitions(${PROJECT_NAME} PRIVATE LINUX_BUILD)
endif()

# Especificar la ubicación del ejecutable
if(EMSCRIPTEN)
    set_target_properties(${PROJECT_NAME} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
else()
    set_target_properties(${PROJECT_NAME} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_SOURCE_DIR})
endif()

# --- 5. STATIC ANALYSIS TARGETS ---

find_program(CLANG_TIDY_EXE NAMES clang-tidy)
find_program(CLANG_FORMAT_EXE NAMES clang-format)
find_program(CPPCHECK_EXE NAMES cppcheck)

# Recopilar todos los archivos fuente, excluyendo external/
file(GLOB_RECURSE ALL_SOURCE_FILES
    "${CMAKE_SOURCE_DIR}/source/*.cpp"
    "${CMAKE_SOURCE_DIR}/source/*.hpp"
    "${CMAKE_SOURCE_DIR}/source/*.h"
)
list(FILTER ALL_SOURCE_FILES EXCLUDE REGEX ".*/external/.*")

# Para cppcheck, pasar solo .cpp (los headers se procesan transitivamente).
# Si pasamos .hpp como TUs independientes, cppcheck reporta falsos positivos de
# 'unusedStructMember' porque no hace análisis cross-TU y ve miembros de clase
# cuyo uso vive en un .cpp distinto.
set(CPPCHECK_SOURCES ${ALL_SOURCE_FILES})
list(FILTER CPPCHECK_SOURCES INCLUDE REGEX ".*\\.cpp$")
list(FILTER CPPCHECK_SOURCES EXCLUDE REGEX ".*_spv\\.h$")

# Targets de clang-tidy
if(CLANG_TIDY_EXE)
    # En macOS con clang-tidy de Homebrew LLVM, es necesario pasar el sysroot
    # explícitamente para que encuentre los headers del sistema (string, memory, etc.)
    if(APPLE)
        execute_process(
            COMMAND xcrun --show-sdk-path
            OUTPUT_VARIABLE MACOS_SDK_PATH
            OUTPUT_STRIP_TRAILING_WHITESPACE
        )
        set(TIDY_EXTRA_ARGS --extra-arg=-isysroot --extra-arg=${MACOS_SDK_PATH})
    endif()

    add_custom_target(tidy
        COMMAND ${CLANG_TIDY_EXE}
            -p ${CMAKE_BINARY_DIR}
            ${TIDY_EXTRA_ARGS}
            ${ALL_SOURCE_FILES}
        WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
        COMMENT "Running clang-tidy..."
    )

    add_custom_target(tidy-fix
        COMMAND ${CLANG_TIDY_EXE}
            -p ${CMAKE_BINARY_DIR}
            --fix
            ${TIDY_EXTRA_ARGS}
            ${ALL_SOURCE_FILES}
        WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
        COMMENT "Running clang-tidy with fixes..."
    )
else()
    message(STATUS "clang-tidy no encontrado - targets 'tidy' y 'tidy-fix' no disponibles")
endif()

# Targets de clang-format
if(CLANG_FORMAT_EXE)
    add_custom_target(format
        COMMAND ${CLANG_FORMAT_EXE}
            -i
            ${ALL_SOURCE_FILES}
        WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
        COMMENT "Running clang-format..."
    )

    add_custom_target(format-check
        COMMAND ${CLANG_FORMAT_EXE}
            --dry-run
            --Werror
            ${ALL_SOURCE_FILES}
        WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
        COMMENT "Checking clang-format..."
    )
else()
    message(STATUS "clang-format no encontrado - targets 'format' y 'format-check' no disponibles")
endif()

# Targets de cppcheck
if(CPPCHECK_EXE)
    add_custom_target(cppcheck
        COMMAND ${CPPCHECK_EXE}
            --enable=warning,style,performance,portability
            --std=c++20
            --language=c++
            --inline-suppr
            --suppress=missingIncludeSystem
            --suppress=toomanyconfigs
            -D_DEBUG
            -DLINUX_BUILD
            --quiet
            -I ${CMAKE_SOURCE_DIR}/source
            ${CPPCHECK_SOURCES}
        WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
        COMMENT "Running cppcheck..."
    )
else()
    message(STATUS "cppcheck no encontrado - target 'cppcheck' no disponible")
endif()